home *** CD-ROM | disk | FTP | other *** search
/ Ahoy 1985 October / Ahoy_Magazine_85-10_1985_Double_L.d64 / mycroft mews (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  12KB  |  306 lines
  1. 10 rem "mystery at mycroft mews"
  2. 20 s=54272:forj=0to24:pokes+j,0:next:pokes+24,15
  3. 30 poke53280,0:poke53281,0:poke53283,6:print"[147]"chr$(8)chr$(142);
  4. 40 m$="[223][169][157][157][157][157] [223][169] [157][157][157][157]    [157][157][157][157] [212][217] [157][157][157][157][146][223][205] [205] [145][157] [157][145] [157][145] [157][145][223][146]"
  5. 50 print"[147][150]"tab(8)m$"ystery at":print"[129]"tab(16)m$"ycroft"
  6. 60 print"[158]"tab(24)m$"ews":gosub20000
  7. 100 for j=49152to49220:readx:a=a+x:pokej,x:next:poke785,0:poke786,192
  8. 110 ifa<>8919thenprint"[147]ml data error":stop
  9. 120 deffnr(x)=int(rnd(1)*x)+1:y=rnd(-ti):deffnsx(x)=-(x>6)
  10. 140 v=53248:pokev+28,1:pokev+39,4:pokev+37,15:pokev+38,6:pokev+27,0:poke2040,13
  11. 150 forj=832to894step3:pokej,0:pokej+1,0:pokej+2,0:ifj<=880thenreada:pokej,a
  12. 160 next
  13. 170 mx=fnr(3):mv=fnr(12):mw=fnr(12):mr=fnr(12):ifmv=mrthen170
  14. 180 i=12:diml(74),u1(i),u2(i),g(i),al(i),h(i),l0(i),sx(1,4)
  15. 190 dimal$(5),it$(16),b$(16),s$(i),h$(i):h$(0)="stamp collector"
  16. 200 forj=1to16:readb$(j),it$(j)
  17. 210 i=fnr(16):ifl(58+i)>0then210
  18. 220 l(58+i)=j:l(12+j)=16:ifj>12then250
  19. 230 reads$(j),h$(j):l(j)=j:al(j)=fnr(6)-1:h(j)=fnr(12):l0(j)=fnr(15)
  20. 240 l(j+12)=-l0(j):g(j)=fnr(7)-16*(rnd(1)<.5)-32*(rnd(1)<.5)-64*(rnd(1)<.5)
  21. 250 next:l(30)=mx:l(49)=3andmw:l(50)=fnr(40)+20:forj=0to1:fori=0to3
  22. 260 readsx$(j,i):nexti,j:forj=0to5:readal$(j):next:forj=1tomx:readit$(13):next
  23. 270 l(mv)=0:l(25)=-mv:al(mr)=fnr(3)-1
  24. 275 l0(mw)=mr:if-l(12+mw)=mrthenl(12+mw)=-fnr(15):goto275
  25. 280 g(mv)=fnr(7)-8*(mx=2):ifmx<3theng(mv)=g(mv)or6
  26. 290 g(mr)=g(mr)or2^(mx+3):ifmx<3theng(mr)=g(mr)and251
  27. 300 printtab(8)"[156]how many players? (1-6)":poke198,0
  28. 310 wait198,1:geta$:a=val(a$):ifa<1ora>6then310
  29. 320 l(57)=a:forj=1toa:l(36+j)=5:l(42+j)=7:l(30+j)=17:next:p=1:dimsc$(a)
  30. 400 pokev+17,27:print"[147]":pokev+21,0
  31. 410 fory=1to4:print"   ";:forx=1to4:h=(x*4-y-6-2*(h=12))and15
  32. 420 print"[155][169]  [146][169][205][157][157][180][170][157][157][204][186][157][157][157][157][157][145]";:poke646,h:print"[163][163][163][157][157][157]  [146][145][145]   ";
  33. 430 next:print"":next:print"player #"p"":ifl(57)-l(58)=1then500
  34. 440 print"enter your secret code!":poke198,0:wait198,2:geta$,b$
  35. 450 ifsc$(p)=""thensc$(p)=a$+b$
  36. 460 ifsc$(p)=a$+b$then500
  37. 470 j=usr(33000):gosub20000:gosub20100:goto440
  38. 500 x=l(36+p):y=l(42+p):pokes+1,33:pokes+5,9:pokes+6,0
  39. 510 poke198,0:gosub20100:print"move to building desired":gosub20500
  40. 520 gosub20300:gosub20100:if(xand1)or(yand1)then520
  41. 530 j=2*y+x/2-8:b=l(58+j):ifb<>mvthen600
  42. 540 ifl(26)=p+100orabs(l(26))=mvorl(30+p)=mvthen600
  43. 550 print"that building is locked. try another.":goto520
  44. 600 l(30+p)=b:l(36+p)=x:l(42+p)=y:pokes+6,96:pokes+4,33:forj=0to12:pokes+1,33-j
  45. 610 u2(j)=0:u1(j)=0:next:pokes+4,0:pokev+21,0:print"[147][154]you are at the "b$(b)".[155]"
  46. 620 print"you have ";:ifl(50+p)thenprint"the "it$(l(50+p))".":goto640
  47. 630 print"no item."
  48. 640 i=0:print"you see:[152]":forj=1to12
  49. 645 ifl(j)=bthenprints$(j):u2(1)=u2(1)+1:i=1:u2(5)=j
  50. 650 next:forj=1to16:ifl(j+12)=bthenprint"the "it$(j):u2(2)=u2(2)+1:i=1
  51. 660 next:forj=1tol(57):ifj=porl(j+30)<>bthen690
  52. 670 print"player #"j;:i=1:u2(3)=u2(3)+1:ifl(50+j)=0thenprint:goto690
  53. 680 print"<with an item>":u2(4)=u2(4)+1
  54. 690 next:ifi=0thenprint"nothing worth mentioning."
  55. 695 print"[155]press button for turn options":gosub20400
  56. 700 print"[147][150]turn options...":my=1:y=1:pokev+17,91:u1(1)=1:print"search"
  57. 720 ifu2(1)thenprint"interrogate suspect":my=2:u1(2)=2
  58. 730 ifu2(2)oru2(4)thenprint"take item":my=my+1:u1(my)=3
  59. 740 ifb=16and(u2(2)orl(50+p))thenprint"fingerprint item":my=my+1:u1(my)=4
  60. 750 ifb=16thenprint"accuse a suspect":my=my+1:u1(my)=5
  61. 760 ifb=14thenprint"read coroner's report":my=my+1:u1(my)=6
  62. 770 ifl(25)=100+porl(25)=bthenprint"read "it$(13):my=my+1:u1(my)=7
  63. 780 ifl(50+p)thenprint"drop or hide item carried":my=my+1:u1(my)=8
  64. 790 ifb<3orb=7thenprint"examine "b$(b)" records":my=my+1:u1(my)=9
  65. 800 gosub20100:print"choose one":gosub20600:i=u1(y):y=1:print"[147][154]";
  66. 810 onigosub1000,2000,1400,1100,5000,1200,1500,1300,1600:j=fre(0)
  67. 900 poke214,22:print:print"[158] *** press button to end your turn ***";:gosub20400
  68. 910 print"[147][154]"tab(12)"player #"p:printtab(12)"end of turn"
  69. 915 j=usr(33000):gosub20000
  70. 920 p=p+1:ifp>l(57)then950
  71. 930 ifl(30+p)>0then400
  72. 940 goto920
  73. 950 forj=1to12:l(j)=fnr(16):ifl(j)=mvthenl(j)=j
  74. 960 next:forj=31to36:ifl(j)<13thenl(l(j))=l(j)
  75. 970 next:l(mv)=0:p=1:goto930
  76. 1000 print"search":print"[155]you find:[152]":i=0
  77. 1010 forj=1to16:ifl(j+12)<>-bthen1030
  78. 1020 ifrnd(1)<.6orl(50+p)=15theni=1:print"the "it$(j):l(j+12)=b
  79. 1030 next:ifi=0thenprint"nothing of interest":return
  80. 1040 print"[154]take an item?  ";:gosub20700:ifyn=0thenreturn
  81. 1050 u2(4)=0:print"[147][154]";:y=1:goto1400
  82. 1100 print"fingerprint item":print"[155]which one?":my=0
  83. 1110 forj=1to16:ifl(j+12)=bthenprint"the "it$(j):my=my+1:u1(my)=j
  84. 1120 next:i=l(p+50):ifithenprint"the "it$(i):my=my+1:u1(my)=i
  85. 1130 gosub20600:i=u1(y):print"[147][154]lab report:":print"the "it$(i)
  86. 1140 print"bears the fingerprints of":l(i+12)=b:ifl(p+50)=ithenl(p+50)=0
  87. 1150 ifi<13thenifl0(i)<13thenprints$(l0(i))".":return
  88. 1160 ifi=13thenprints$(mv)".":return
  89. 1170 print"no suspect.":return
  90. 1200 print"coroner's report:":x=abs(mv>6):print"subject is "sx$(x,0)","
  91. 1210 print"approximately"l(50)"years of age.":j=usr(34000+l(49)*10)
  92. 1220 readt$:print"subject apparently was "t$
  93. 1230 readt$:print"by a "t$".":return
  94. 1300 print"drop or hide item carried":print"[155]do you want to hide the"
  95. 1310 i=l(50+p):printit$(i)"?  ";:gosub20700:l(50+p)=0
  96. 1320 print:print"[155]you drop the "it$(i)"."
  97. 1330 l(12+i)=b*(1+yn*2):ifynthenprint"item hidden."
  98. 1340 fori=1to200:next:poke198,0:return
  99. 1400 print"take item":print"[155]which one?":my=0
  100. 1410 forj=1to16:ifl(j+12)=bthenprint"the "it$(j):my=my+1:u1(my)=j
  101. 1420 next:ifu2(4)=0then1450
  102. 1430 forj=1tol(57):ifj=porl(j+30)<>borl(j+50)=0thennext:goto1450
  103. 1440 print"player #"j"[157]'s item":my=my+1:u1(my)=100+j:next
  104. 1450 gosub20600:i=u1(y):ifi>100theni=l(i-50):l(u1(y)-50)=0
  105. 1460 print"[147]":j=l(50+p):ifjthenprint"you drop the "it$(j)".":l(j+12)=b
  106. 1470 print"you take the "it$(i)".":l(50+p)=i:l(i+12)=100+p:return
  107. 1500 print"extract from the "it$(13):print"of "s$(mv)":"
  108. 1510 j=usr(34000+l(30)*100)
  109. 1520 readt$:i=val(t$):ifi=0thenprintt$:goto1520
  110. 1530 print"[152]":forj=1to12:ifiandg(j)thenprint"    "s$(j)
  111. 1540 next:print:j=fre(0):return
  112. 1600 print"examine "b$(b)" records":print"[155]about whom?"
  113. 1610 forj=1to12:prints$(j):next:my=12:gosub20600
  114. 1620 print"[147][154]"b$(b)" report":print"on "s$(y)":":onbgoto1650,1690
  115. 1630 j=usr(34400):forj=1to(g(y)and7):readt$:next
  116. 1640 printtab(8)t$" account":return
  117. 1650 if(g(y)and40)=0thenprint"subject not in records.":return
  118. 1660 ifg(y)and8thenprint"subject recently drew up a new will.":return
  119. 1670 print"subject can expect to inherit":print"substantial wealth in the near"
  120. 1680 print"future.":return
  121. 1690 if(g(y)and64)=0thenprint"subject not in files":return
  122. 1700 print"patient severely paranoiac, envious and"
  123. 1710 print"resentful of others. may show sudden"
  124. 1720 print"homicidal fury.":return
  125. 2000 y=1:q=3:h=0:q4=-1:ifu2(1)=1thenq1=u2(5):goto2100
  126. 2010 print"interrogate a suspect":print"[155]which one?":my=0
  127. 2020 forj=1to12:ifl(j)=bthenprints$(j):my=my+1:u1(my)=j
  128. 2030 next:gosub20600:q1=u1(y):y=1
  129. 2100 print"[147][154]interrogate "s$(q1):my=13:poke198,0:i=12:ifq4=0then2120
  130. 2110 print"[155]about whom?":forj=1toi:prints$(j):next
  131. 2115 print"<an item>":goto2130
  132. 2120 print"[155]about what item?":forj=1toi:print"the "it$(j):next
  133. 2125 print"<a suspect>"
  134. 2130 ifh<>0thenpoke782,y:sys49189:h=0
  135. 2140 gosub20600:h=1:ify=13thenh=0:q4=notq4:goto2100
  136. 2150 q2=y:q=q-1:yn=(rnd(1)<.75):gosub20100:onq4+2gosub2200,3000
  137. 2160 forj=1to100:next:poke198,0:ifqthen2130
  138. 2170 j=fre(0):return
  139. 2200 q3=fnr(12):ifq3=mvorq3=q1then2200
  140. 2210 t$=s$(q2):ifrnd(1)>.2orl(28)=100+pthen2240
  141. 2220 l(29)=(l(29)+1)and1:ifl(29)thenprint"i never gossip.":return
  142. 2230 print"i don't have time to talk now.":return
  143. 2240 x=fnsx(q2):ifq2=q1then2500
  144. 2250 ifq2=mvthen2400
  145. 2260 onfnr(7)goto2290,2300,2300,2320,2320,2360
  146. 2270 ifal(q1)<3oral(q1)<>al(q2)then2285
  147. 2280 print"i was with "t$:print"on the night of the murder.":return
  148. 2285 print"i can't confirm "sx$(x,3)" alibi.":return
  149. 2290 printt$" did it, i'm sure!":return
  150. 2300 printt$:i=fnr(3):j=2*i-1:ifg(q2)and2^(3+i)thenj=j-1
  151. 2310 gosub20800:return
  152. 2320 gosub20900:ifrnd(1)>.5then2370
  153. 2340 printt$" owns":a=-1*yn:ifa=0thenprint"a new car.":return
  154. 2350 print"the "it$(a)".":return
  155. 2360 a=h(q2)
  156. 2370 printt$" is":print"a "h$(a)".":return
  157. 2400 onfnr(3)goto2440,2470
  158. 2410 iffnr(3)=1thenprint"how tragic that":printsx$(x,1)"'s gone.":return
  159. 2420 iffnr(2)=1thenprint"i think it was suicide.":return
  160. 2430 print"i think that "s$(q3):print"murdered "sx$(x,2)".":return
  161. 2440 i=fnr(4)-1:ifyntheni=l(49)
  162. 2450 print"i heard that "sx$(x,1)" was killed":j=usr(34000+i*10)
  163. 2460 readt$,t$:print"by a "t$".":return
  164. 2470 i=fnr(3):ifyntheni=l(30)
  165. 2480 print"i heard that "sx$(x,1)" was":j=i+5:gosub20800:return
  166. 2500 onfnr(4)goto2530,2540,2550
  167. 2510 gosub20900:ifa=0thenprint"i own a new car.":return
  168. 2520 print"i own the":printit$(a)".":return
  169. 2530 print"i was "al$(al(q1)):print"on the night of the crime.":return
  170. 2540 a=h(q1):goto2560
  171. 2550 gosub20900
  172. 2560 print"i am a "h$(a)".":return
  173. 3000 onfnr(5)goto3030,3060,4030,4050
  174. 3010 print"i ";:ifnot(l0(q2)=q1)or(q1=mr)thenprint"do not ";
  175. 3020 print"own the":printit$(q2)".":return
  176. 3030 ifyn=0or(q2=mwandq1=mr)orl0(q2)>12then3050
  177. 3035 ifl0(q2)=q1then3010
  178. 3040 prints$(l0(q2))" owns":print"the "it$(q2)".":return
  179. 3050 print"i'm not sure who owns":print"the "it$(q2)".":return
  180. 3060 i=fnr(57):x=abs(l(12+q2)):ifx<100then4000
  181. 3070 x=x-100:ifyn=0thenx=i
  182. 3080 ifx=pthenprint"you have the "it$(q2)",":print"don't you?":return
  183. 3090 print"i think that player #"x"has":print"the "it$(q2)".":return
  184. 4000 ifyn=0or(q2=mwandq1=mr)thenj=9:goto20800
  185. 4010 ifx=q1thenprint"i've got the":printit$(q2)".":return
  186. 4020 print"i saw that at the ":printb$(x)".":return
  187. 4030 print"the "it$(q2)" was ";:i=(q2=mw)=yn:ifi=0orq1=mrthenprint"not";
  188. 4040 print:print"the murder weapon.":return
  189. 4050 x=0:forj=1to12:ifh(j)=q2andrnd(1)>.5thenx=j
  190. 4060 next:i=l0(q2):ifi>12theni=0
  191. 4070 ifrnd(1)<.5thenx=i
  192. 4080 ifx=0thenj=9:goto20800
  193. 4090 prints$(x)" is":print"a "h$(q2)".":return
  194. 5000 print"[150]accuse!":print"[155]who was killed?":my=12:q=-1
  195. 5010 forj=1to12:prints$(j):next:y=1:gosub20600:q=q*(y=mv)
  196. 5020 print"[147][158]accuse!":print"[155]who killed "s$(y)"?":y=1
  197. 5030 forj=1to12:prints$(j):next:gosub20600:h=y:q=q*(h=mr)
  198. 5040 print"[147][153]accuse!":print"[155]what weapon did":prints$(h)" use?":y=1
  199. 5050 forj=1to12:print"the "it$(j):next:gosub20600:q=q*(y=mw)
  200. 5060 print"[147][154]accuse!":print"[155]why did "s$(h):print"commit murder?":y=1
  201. 5070 x=fnsx(h):fora=0to4step2:j=a:printsx$(x,1)" ";:gosub20800:next
  202. 5080 my=3:y=1:gosub20600:q=q*(y=l(30))
  203. 5100 print"[147]the police are arresting":prints$(h)".....":pokes+5,13:pokes+6,0
  204. 5110 pokes+4,65:forj=1to20:pokes+1,16+16*(jand1):fori=1to250:next:next
  205. 5120 pokes+4,0:pokev+17,27:forj=1to600:next:ifqthen5200
  206. 5130 print"no...that was a false arrest.":print"you're out of the game!"
  207. 5140 l(30+p)=0:ifl(50+p)thenl(12+l(50+p))=b:l(50+p)=0
  208. 5150 j=usr(33200):gosub20000:l(58)=l(58)+1:ifl(58)<l(57)thenreturn
  209. 5160 restore:print"[150]all players have been eliminated!"
  210. 5170 print"nobody wins!":print"[156][163][163][163][163][163][163]":goto5300
  211. 5200 print"yes...you've cracked the case!":print"player #"p"wins the game!"
  212. 5210 j=usr(33100)
  213. 5300 gosub20000:print"here is the solution:[152]":prints$(mr)" murdered"
  214. 5310 prints$(mv)" using the":printit$(mw)", because "sx$(fnsx(mr),1)
  215. 5320 j=l(30)*2-2:gosub20800:forj=1to4e3:next:end
  216. 20000 pokes+5,9:pokes+6,192:pokes+3,8:t=ti
  217. 20010 ift>tithen20010
  218. 20020 pokes+4,64:readj:ifj=0then20040
  219. 20030 readx,y:pokes+1,x:pokes,y:t=t+j*9:pokes+4,65:goto20010
  220. 20040 pokes+4,0:return
  221. 20100 sys49178:print"[155]";:return
  222. 20200 j=not(peek(56320)andpeek(56321))and31:a=0:ifpeek(198)thengeta$:a=asc(a$)
  223. 20210 bt=(jand16)or(a=13):ifbtthenreturn
  224. 20220 dx=sgn((jand8)-(a=135)-(jand4)+(a=134))
  225. 20230 dy=sgn((jand2)-(a=136)-(jand1)+(a=133)):ifdxordythenreturn
  226. 20240 goto20200
  227. 20300 gosub20200:ifbtthenreturn
  228. 20310 ifabs(dx+x-5)>3thendx=0
  229. 20320 ifabs(dy+y-7)>3thendy=0
  230. 20330 ifdx=0anddy=0then20300
  231. 20340 fori=1to4:x=x+dx/4:y=y+dy/4:gosub20500:pokes+1,30+3*(1andi)
  232. 20350 pokes+4,17:forj=1to40:next:pokes+4,0:next:goto20300
  233. 20400 poke198,0
  234. 20410 gosub20200:ifbt=0then20410
  235. 20420 return
  236. 20500 pokev,x*32-1:pokev+1,y*20+12:pokev+21,1:return
  237. 20600 poke782,y:sys49189
  238. 20610 gosub20200:ifbtthenreturn
  239. 20620 x=y+dy:ifx<1orx>mythenx=-(x>my)-my*(x<1)
  240. 20630 ifx=ythen20610
  241. 20640 poke782,y:sys49189:y=x:goto20600
  242. 20700 poke190,0:yn=-1
  243. 20710 printchr$(-18*yn)"yes[146] "chr$(yn*2+18)"no [146][157][157][157][157][157][157][157]";
  244. 20720 gosub20200:ifbtthenreturn
  245. 20730 ifdxthenyn=notyn:goto20710
  246. 20800 j=usr(35000+10*j):readt$:printt$".":return
  247. 20840 goto20720
  248. 20900 a=0:x=1:forj=1to12:ifl0(j)=q2andrnd(1)<1/xthena=j:x=x+1
  249. 20910 next:return
  250. 30000 data8,11,48,12,10,143,4,9,104,4,10,143,4,11,48,12,13,78
  251. 30010 data4,14,24,12,8,97,0
  252. 31000 data32,247,183,32,19,166,144,13,165,95,233,1
  253. 31010 data133,65,165,96,233,0,133,66,96,162,17,76
  254. 31020 data55,164,169,32,160,80,136,153,80,4,208,250
  255. 31030 data96,169,4,133,252,169,160,24,105,40,144,2
  256. 31040 data230,252,136,208,246,133,251,160,40,136,177,251
  257. 31050 data73,128,145,251,192,0,208,245,96
  258. 32000 data20,20,20,0,170,170,170,170,190,190,190,125,60,60,60,60,85
  259. 32100 datalaw office,elephant gun,phyllis writ,big-game hunter
  260. 32110 datamental health clinic,antique crossbow,dr. wilma libido
  261. 32120 data"[157]n archery expert",delicatessen,baseball bat,hannah nosh,sports fan
  262. 32130 datatheatre,box of rat poison,edith scrim,pest exterminator,hotel
  263. 32140 dataarquebus,cheryl valise,gun collector,art gallery,scimitar
  264. 32150 datadesiree ochre,master fencer,bank,brass candlestick,emilio lucre
  265. 32160 datacandelabra fancier,library,jar of sleeping pills,morton screed
  266. 32170 data"[157]n insomniac",bakery,.45 automatic,joseph cruller,marksman,pawn shop
  267. 32180 dataknitting needle,norman hock,champion knitter,church,ball-peen hammer
  268. 32190 datarev. arthur transept,tool collector,pub,vial of snake venom
  269. 32200 dataedgar quaff,herpetologist,shopping mall,item,morgue,master key
  270. 32210 datawarehouse,magnifying lens,police station,police badge
  271. 32300 datafemale,she,her,her,male,he,him,his
  272. 32400 dataat home alone,sick in bed,out of town,at a party
  273. 32410 dataat the theatre,in church
  274. 32900 dataledger,will,diary
  275. 33000 data2,15,210,2,14,24,2,12,143,2,11,218,4,9,247,4,7,233,4,10,143,0
  276. 33100 data4,28,49,4,37,162,4,42,62,2,47,107,4,37,162,2,42,62,2,47,107,2,37,162
  277. 33110 data2,42,62,4,56,99,2,42,62,2,47,207,1,42,62,1,37,162,2,42,62,8,28,49,0
  278. 33200 data2,25,30,2,23,181,2,31,165,2,35,134,2,47,107,2,37,162,2,35,134
  279. 33210 data2,47,107,2,37,162,2,35,134,2,31,165,2,29,223,4,31,165,0
  280. 34000 datapoisoned,"[157]n unidentified toxin"
  281. 34010 datashot,gun
  282. 34020 dataimpaled,sharp weapon
  283. 34030 databludgeoned,blunt instrument
  284. 34100 datai have threatened to tell the police
  285. 34110 dataall that i know about their criminal
  286. 34120 dataactivities if any of these people
  287. 34130 datadoesn't pay me another $9000 by,midnight sunday...,16
  288. 34200 datai hereby bequeath one hundred million
  289. 34210 datadollars to each of these loyal and
  290. 34220 datafaithful friends...,32
  291. 34300 datadear diary---,i found another anonymous letter in the
  292. 34310 datamail this morning. my life is in danger
  293. 34320 datafrom a jealous lunatic. the handwriting
  294. 34330 datacould be that of any of these people...,64
  295. 34400 datano,overdrawn,minimum,average,significant,substantial,maximum
  296. 35000 datawas being blackmailed
  297. 35010 datahas no secrets to hide
  298. 35020 datawill inherit millions
  299. 35030 datais not a legatee
  300. 35040 datais a homicidal maniac
  301. 35050 datais as sane as i am
  302. 35060 dataa blackmailer
  303. 35070 dataextremely wealthy
  304. 35080 datareceiving death threats
  305. 35090 datai don't know where that object is
  306.